%compare-lengths
%compare-strncmp
%define word-array-name gearman_command_string_st
%define class-name String2gearman_command_t
%global-table
%ignore-case
%language=C++
%readonly-tables
%includes

%{ 
/*  vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
 * 
 *  Gearmand client and server library.
 *
 *  Copyright (C) 2013 Data Differential, http://datadifferential.com/
 *  All rights reserved.
 *
 *  Redistribution and use in source and binary forms, with or without
 *  modification, are permitted provided that the following conditions are
 *  met:
 *
 *      * Redistributions of source code must retain the above copyright
 *  notice, this list of conditions and the following disclaimer.
 *
 *      * Redistributions in binary form must reproduce the above
 *  copyright notice, this list of conditions and the following disclaimer
 *  in the documentation and/or other materials provided with the
 *  distribution.
 *
 *      * The names of its contributors may not be used to endorse or
 *  promote products derived from this software without specific prior
 *  written permission.
 *
 *  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 *  "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 *  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 *  A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
 *  OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 *  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 *  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 *  DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 *  THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 *  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 *  OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 *
 */

#include "gear_config.h"
#include <libgearman/common.h>

#include <libgearman-1.0/visibility.h>
#include <libgearman/command.h>

#include "libgearman/assert.hpp"
#include "libgearman/command.h"

%}

struct gearman_command_string_st
{
  const char *name;
  const gearman_command_t code;
};
%%
TEXT, GEARMAN_COMMAND_TEXT
CAN_DO, GEARMAN_COMMAND_CAN_DO
CANT_DO, GEARMAN_COMMAND_CANT_DO
RESET_ABILITIES, GEARMAN_COMMAND_RESET_ABILITIES
PRE_SLEEP, GEARMAN_COMMAND_PRE_SLEEP
UNUSED, GEARMAN_COMMAND_UNUSED
NOOP, GEARMAN_COMMAND_NOOP
SUBMIT_JOB, GEARMAN_COMMAND_SUBMIT_JOB 
JOB_CREATED, GEARMAN_COMMAND_JOB_CREATED
GRAB_JOB, GEARMAN_COMMAND_GRAB_JOB
NO_JOB, GEARMAN_COMMAND_NO_JOB
JOB_ASSIGN, GEARMAN_COMMAND_JOB_ASSIGN 
WORK_STATUS, GEARMAN_COMMAND_WORK_STATUS
WORK_COMPLETE, GEARMAN_COMMAND_WORK_COMPLETE 
WORK_FAIL,GEARMAN_COMMAND_WORK_FAIL
GET_STATUS,GEARMAN_COMMAND_GET_STATUS
ECHO_REQ, GEARMAN_COMMAND_ECHO_REQ 
ECHO_RES, GEARMAN_COMMAND_ECHO_RES 
SUBMIT_JOB_BG, GEARMAN_COMMAND_SUBMIT_JOB_BG 
ERROR, GEARMAN_COMMAND_ERROR
STATUS_RES, GEARMAN_COMMAND_STATUS_RES
SUBMIT_JOB_HIGH, GEARMAN_COMMAND_SUBMIT_JOB_HIGH 
SET_CLIENT_ID, GEARMAN_COMMAND_SET_CLIENT_ID
CAN_DO_TIMEOUT, GEARMAN_COMMAND_CAN_DO_TIMEOUT
ALL_YOURS, GEARMAN_COMMAND_ALL_YOURS
WORK_EXCEPTION, GEARMAN_COMMAND_WORK_EXCEPTION 
OPTION_REQ, GEARMAN_COMMAND_OPTION_REQ
OPTION_RES, GEARMAN_COMMAND_OPTION_RES
WORK_DATA, GEARMAN_COMMAND_WORK_DATA 
WORK_WARNING, GEARMAN_COMMAND_WORK_WARNING 
GRAB_JOB_UNIQ, GEARMAN_COMMAND_GRAB_JOB_UNIQ
JOB_ASSIGN_UNIQ, GEARMAN_COMMAND_JOB_ASSIGN_UNIQ 
SUBMIT_JOB_HIGH_BG, GEARMAN_COMMAND_SUBMIT_JOB_HIGH_BG 
SUBMIT_JOB_LOW, GEARMAN_COMMAND_SUBMIT_JOB_LOW 
SUBMIT_JOB_LOW_BG, GEARMAN_COMMAND_SUBMIT_JOB_LOW_BG 
SUBMIT_JOB_SCHED, GEARMAN_COMMAND_SUBMIT_JOB_SCHED 
SUBMIT_JOB_EPOCH, GEARMAN_COMMAND_SUBMIT_JOB_EPOCH 
SUBMIT_REDUCE_JOB, GEARMAN_COMMAND_SUBMIT_REDUCE_JOB
SUBMIT_REDUCE_JOB_BACKGROUND, GEARMAN_COMMAND_SUBMIT_REDUCE_JOB_BACKGROUND
GRAB_JOB_ALL, GEARMAN_COMMAND_GRAB_JOB_ALL 
JOB_ASSIGN_ALL, GEARMAN_COMMAND_JOB_ASSIGN_ALL 
GET_STATUS_UNIQUE, GEARMAN_COMMAND_GET_STATUS_UNIQUE
STATUS_RES_UNIQUE, GEARMAN_COMMAND_STATUS_RES_UNIQUE
%%
